mirror of
https://github.com/NixOS/nix
synced 2025-06-25 06:31:14 +02:00
b86a76044e
- Some headers were completely redundant and have been removed. - Other headers have been turned private. - Unnecessary meson.build code has been removed. - libutil-tests now has a private config header, where previously it had none. This removes the need to expose a package version macro publicly.
76 lines
1.7 KiB
Meson
76 lines
1.7 KiB
Meson
project('nix-util-c', 'cpp',
|
|
version : files('.version'),
|
|
default_options : [
|
|
'cpp_std=c++2a',
|
|
# TODO(Qyriad): increase the warning level
|
|
'warning_level=1',
|
|
'errorlogs=true', # Please print logs for tests that fail
|
|
],
|
|
meson_version : '>= 1.1',
|
|
license : 'LGPL-2.1-or-later',
|
|
)
|
|
|
|
cxx = meson.get_compiler('cpp')
|
|
|
|
subdir('nix-meson-build-support/deps-lists')
|
|
|
|
configdata = configuration_data()
|
|
|
|
deps_private_maybe_subproject = [
|
|
dependency('nix-util'),
|
|
]
|
|
deps_public_maybe_subproject = [
|
|
]
|
|
subdir('nix-meson-build-support/subprojects')
|
|
|
|
configdata.set_quoted('PACKAGE_VERSION', meson.project_version())
|
|
|
|
config_h = configure_file(
|
|
configuration : configdata,
|
|
output : 'config-util.h',
|
|
)
|
|
|
|
add_project_arguments(
|
|
# TODO(Qyriad): Yes this is how the autoconf+Make system did it.
|
|
# It would be nice for our headers to be idempotent instead.
|
|
|
|
# From C++ libraries, only for internals
|
|
'-include', 'config-util.hh',
|
|
|
|
language : 'cpp',
|
|
)
|
|
|
|
subdir('nix-meson-build-support/common')
|
|
|
|
sources = files(
|
|
'nix_api_util.cc',
|
|
)
|
|
|
|
include_dirs = [include_directories('.')]
|
|
|
|
headers = files(
|
|
'nix_api_util.h',
|
|
)
|
|
|
|
# TODO don't install this once tests don't use it.
|
|
headers += files('nix_api_util_internal.h')
|
|
|
|
subdir('nix-meson-build-support/export-all-symbols')
|
|
subdir('nix-meson-build-support/windows-version')
|
|
|
|
this_library = library(
|
|
'nixutilc',
|
|
sources,
|
|
config_h,
|
|
dependencies : deps_public + deps_private + deps_other,
|
|
include_directories : include_dirs,
|
|
link_args: linker_export_flags,
|
|
prelink : true, # For C++ static initializers
|
|
install : true,
|
|
)
|
|
|
|
install_headers(headers, subdir : 'nix', preserve_path : true)
|
|
|
|
libraries_private = []
|
|
|
|
subdir('nix-meson-build-support/export')
|