import crafttweaker.item.IItemStack;

var items as IItemStack[] = loadedMods["adchimneys"].items;

function changeRecipe(item as IItemStack) as bool {
    // do not apply function to these items
    if (item.definition.id == <adchimneys:smoker>.definition.id) return false;
    if (item.damage != 0) return false;

    var pump as IItemStack = item.definition.makeStack(2);
    var vent as IItemStack = item.definition.makeStack(1);
    recipes.remove(pump);

    recipes.addShaped(
        pump,
        [
            [vent, <minecraft:repeater>, vent],
            [<minecraft:repeater>, <ore:blockCoal>, <minecraft:repeater>],
            [vent, <galacticraftcore:air_fan>, vent]
        ]
    );

    return true;
}

for i, item in items {
    changeRecipe(item);
}